/********************************************************************************/
/**** This program reads in ASCII data and contains data steps to create     ****/
/**** marginal and experimental poverty measures for 1998 which are also     ****/
/**** contained in the public-use SAS datafile-- povpu98.ssd01.              ****/
/**** This will enable analysts to replicate the experimental poverty        ****/
/**** measures or appropriately recombine thresholds and income measures to  ****/
/**** examine new ones. Also included in this file are variable and value    ****/
/**** label statements.                                                      ****/
/**** For details on construction of various income and threshold measures,  ****/
/**** refer to the P60-205 report on Experimental Poverty Measures           ****/
/**** and its Appendix C.                                                    ****/
/********************************************************************************/

options ps=54 ls=80 fullstimer ;

libname datao '/folder/';
Filename povdat '/folder/povpu98.txt';

Data pov (compress=yes);

Infile povdat;
INPUT
     marsupwt adwk age agecat a_sex combadc combexp combexpm
     def017 def018 def019 defa10a2 defa10a3
     defa4a1 defa4a2 defa4a3 defa5a1 defa5a2
     defa5a3 defa6a1 defa6a2 defa6a3
     defa7a1 defa7a2
  /   defa7a3 defa7a4 defa7a5 defa8a1 defa8a2 defa9a1
     defa9a2 defmort dis dv educ famhead $ fcapgain
     fcaploss feitc fengval ffedtax ffica
     ffpos fh_seq fkind fpersonr fpersons
     fpovcut fsttax ftotval ftype f_mv_fs
     f_mv_sl geo1 hg_reg hisp housub
 /   h_seq moop ms nl1 nl2 nl3
     nl4 nl5 nl6 nl7 nl8 nl9 nl10
     nl11 nl12 nla2a1 nla2a2 nla2a3
     nla2a4 nla2a5 nla2a6 nlgeo npoor1
     npoor2 npoor3 npoor4 npoor5 npoor6 npoor7 npoor8
     npoor9 npoor10 npoor11 npoor12 pf_seq ph_seq
/    poor1 pova10a1 pova10a2 pova10a3 pova1a1 pova1a2 pova1a3
     pova2a1 pova2a2 pova2a3 pova2a4 pova2a5 pova2a6 pova3a1
     pova4a1 pova4a2 pova4a3 pova5a1 pova5a2 pova5a3 pova6a1
     pova6a2 pova6a3 pova7a1 pova7a2 pova7a3 pova7a4
     pova7a5 pova8a1 pova8a2 pova9a1 pova9a2 pov_univ $
     ppposold prcitshp race rac_hisp $ scaleb scalec
     scaleph scalepl scalepm scalesq severe
     hea thrhigh thrir thrlow thrmed;
run;

Data pov2;
set pov;

/* If using the ASCII data set, use following statement to get
   frequency tallies in 1000s. Note: do not use the following
   statement if reading data from the SAS data sets, where the
   figures are already in 1000s */
marsupwt=marsupwt/100000;

/** Calculate poverty measures **/
if pov_univ=1 then DO;   /* Do loop for those in the poverty universe */

/* official poverty measure */
poor1=0;
if ftotval lt fpovcut then poor1=1;

/**** resource definintions used in various experimental poverty measures ****/
def001= ftotval;               /* official income definition */
def013= def001 - ffica + fcapgain - fcaploss - ffedtax - fsttax + feitc
        + f_mv_fs + housub + f_mv_sl + fengval -  moop;
def017= def013 - combexp;      /* NAS Panel definition */
def018= def013 - combexpm;     /* NAS but with SIPP median child care method */
def019= def013 - combadc;      /* NAS but with AFDC cc method */

/****  Below are thresholds used in experimental poverty measures  ****/
/** Note that the standardization factor needed to make the standardized      **/
/** experimental rates equal the official rate need to be adjusted when       **/
/** using this public use datafile. See the Readme file for more information. **/

nl1=16401*scalepm*geo1*.9119;   /* #1: NAS panel method, standardized */
nl2=16401*scalepm*geo1;         /* #2: NAS panel method, unstandardized */

nl3=16401*scalepm*geo1*.8962;   /* #3: NAS standardized, will have diff def00 than 1 */
nl4=16401*scalepm*geo1;         /* #4: NAS unstandardized will have diff def00 than 2*/

nl5=16401*scalepm*.9031;         /* #5: NAS panel standardized, but no geography */
nl6=16401*scalepm;               /* #6: NAS panel unstandardized, but no geog */

nl7=16401*scaleb*geo1*.8877;    /* #7: 3 parameter scale, standardized */
nl8=16401*scaleb*geo1;          /* #8: 3 parameter scale, untandardized */

nl9=16401*scaleb*.8791;         /* #9: standardized 3 parameter, but no geography */
nl10=16401*scaleb;               /* #10: unstandardized 3 parameter, but no geog */

nl11=16401*scalepm*geo1*.9087;   /* #1: NAS panel method w/ diff def00, standardized */
nl12=16401*scalepm*geo1;         /* #2: NAS panel method w diff def00, unstandardized */


/* 12 experimental poverty measures */
npoor1=0;
if def017 lt nl1 then npoor1=1;
npoor2=0;
if def017 lt nl2 then npoor2=1;
npoor3=0;
if def018 lt nl3 then npoor3=1;
npoor4=0;
if def018 lt nl4 then npoor4=1;
npoor5=0;
if def017 lt nl5 then npoor5=1;
npoor6=0;
if def017 lt nl6 then npoor6=1;
npoor7=0;
if def019 lt nl7 then npoor7=1;
npoor8=0;
if def019 lt nl8 then npoor8=1;
npoor9=0;
if def019 lt nl9 then npoor9=1;
npoor10=0;
if def019 lt nl10 then npoor10=1;
npoor11=0;
if def019 lt nl11 then npoor11=1;
npoor12=0;
if def019 lt nl12 then npoor12=1;

/******************************************************************************/
/** Below are various marginal poverty measures contained in the Poverty     **/
/**  Report. Each poverty measure has four suffix numbers and letters. The   **/
/**  first three refer to the P-60 report table in which the poverty rates   **/
/**  are listed, and the last differentiates the poverty measures within the **/
/**  table. For example, variable pova1a1 suffix refer to the first of three **/
/**  marginal poverty measures listed in Appendix table a1a                  **/
/******************************************************************************/

pova1a1=0;
if ftotval lt thrhigh then pova1a1=1;

pova1a2=0;
if ftotval lt thrmed then pova1a2=1;

pova1a3=0;
if ftotval lt thrlow then pova1a3=1;

pova2a1=0;
nla2a1=16530*scalepl;
if ftotval lt nla2a1 then pova2a1=1;

pova2a2=0;
nla2a2=16530*scaleph;
if ftotval lt nla2a2 then pova2a2=1;

pova2a3=0;
nla2a3=16530*scalepm;
if ftotval lt nla2a3 then pova2a3=1;

pova2a4=0;
nla2a4=16530*scalesq;
if ftotval lt nla2a4 then pova2a4=1;

pova2a5=0;
nla2a5=16530*scaleb;
if ftotval lt nla2a5 then pova2a5=1;

pova2a6=0;
nla2a6=16530*scalec;
if ftotval lt nla2a6 then pova2a6=1;

pova3a1=0;
nlgeo=fpovcut*geo1;
if ftotval lt nlgeo then pova3a1=1;

pova4a1=0;
defa4a1=ftotval+f_mv_fs;
if defa4a1 lt fpovcut then pova4a1=1;

pova4a2=0;
defa4a2=ftotval+f_mv_sl;
if defa4a2 lt fpovcut then pova4a2=1;

pova4a3=0;
defa4a3=ftotval+f_mv_fs+f_mv_sl;
if defa4a3 lt fpovcut then pova4a3=1;

pova5a1=0;
defa5a1=ftotval+housub;
if defa5a1 lt fpovcut then pova5a1=1;

pova5a2=0;
defa5a2=ftotval+fengval;
if defa5a2 lt fpovcut then pova5a2=1;

pova5a3=0;
defa5a3=ftotval+housub+fengval;
if defa5a3 lt fpovcut then pova5a3=1;

pova6a1=0;
defa6a1=ftotval-combexp;
if defa6a1 lt fpovcut then pova6a1=1;

pova6a2=0;
defa6a2=ftotval-combadc;
if defa6a2 lt fpovcut then pova6a2=1;

pova6a3=0;
defa6a3=ftotval-combexpm;
if defa6a3 lt fpovcut then pova6a3=1;

pova7a1=0;
defa7a1=ftotval-ffica;
if defa7a1 lt fpovcut then pova7a1=1;

pova7a2=0;
defa7a2=ftotval-ffedtax;
if defa7a2 lt fpovcut then pova7a2=1;

pova7a3=0;
defa7a3=ftotval-fsttax;
if defa7a3 lt fpovcut then pova7a3=1;

pova7a4=0;
defa7a4=ftotval-ffedtax-fsttax+feitc;
if defa7a4 lt fpovcut then pova7a4=1;

pova7a5=0;
defa7a5=ftotval-ffedtax-fsttax-ffica+feitc+fcapgain-fcaploss;
if defa7a5 lt fpovcut then pova7a5=1;

pova8a1=0;
defa8a1=ftotval+ f_mv_fs + housub + f_mv_sl + fengval;
if defa8a1 lt fpovcut then pova8a1=1;

pova8a2=0;
defa8a2=ftotval+f_mv_fs+housub+f_mv_sl+fengval+feitc-ffica-ffedtax-fsttax+fcapgain
        - fcaploss;
if defa8a2 lt fpovcut then pova8a2=1;

pova9a1=0;
defa9a1=ftotval-moop;
if defa9a1 lt fpovcut then pova9a1=1;

pova9a2=0;
defa9a2=ftotval-moop;
if defa9a2 lt nl6 then pova9a2=1;

pova10a1=0;
if ftotval lt thrir then pova10a1=1;

pova10a2=0;
defa10a2=defmort;
if defa10a2 lt fpovcut then pova10a2=1;

pova10a3=0;
defa10a3=defmort;
if defa10a3 lt thrir then pova10a3=1;

End; /* end pov_univ */

Label
  h_seq=' household id in cps household file'
  fh_seq='houshold id in cps family file'
  ph_seq='household id in cps person file'
  ffpos='family record number'
  pf_seq='family record # in cps person file'
  ppposold='person record number'
  age='11 category age recode'
  agecat='3 category age recode'
  a_sex='sex'
  educ='educational attainment'
  race='3 category race recode'
  hisp='Hispanic indicator'
  rac_hisp='race/hispanic recode'
  fpersons='# persons in family recode'
  fpersonr='# persons in family recode #2'
  adwk='presence of working adult in family'
  prcitshp='citizenship recode'
  dis='disability indicator'
  severe='severe disability indicator'
  hea='health indicator'
  fkind='kind of family'
  ms='marital status indicator'
  hg_reg='region of residence'
  dv='elderly person fam relationship status'
  famhead='family head indicator'
  ftype='family type'
  marsupwt='March supplement final weight'
  ftotval='total family income'
  def017='NAS Panel definition of resources'
  def018='NAS defn except w/ SIPP median cc est'
  def019='NAS defn except w/ AFDC cc valuation'
  defmort='offic inc defn+net return home equity'
  fpovcut='official pov threshold for family'
  thrlow='low $ of NAS threshold range'
  thrmed='midpoint $ of NAS threshold range'
  thrhigh='highpoint of NAS threshold range'
  thrir='threshold with imputed rent'
  scalepl='low NAS equivalence scale-- (A+.7K).65'
  scaleph='high NAS equiv scale-- (A+.7k).75'
  scalepm='mid NAS equiv scale (A+.7k).70'
  scalesq='square root eqiv scale (A+K).50'
  scaleb='three parameter scale'
  scalec='Canadian equivalence scale'
  nl1='threshold used to estimate npoor1 status'
  nl2='threshold used to estimate npoor2 status'
  nl3='threshold used to estimate npoor3 status'
  nl4='threshold used to estimate npoor4 status'
  nl5='threshold used to estimate npoor5 status'
  nl6='threshold used to estimate npoor6 status'
  nl7='threshold used to estimate npoor7 status'
  nl8='threshold used to estimate npoor8 status'
  nl9='threshold used to estimate npoor9 status'
  nl10='threshold used for npoor10 status'
  nl11='threshold used for npoor11 status'
  nl12='threshold used for npoor12 status'
  poor1='official poverty indicator'
  npoor1='pov indicator, NAS standardized method'
  npoor2='pov indicator, NAS unstandardized method'
  npoor3='NAS pov except SIPP median cc, stand'
  npoor4='NAS pov except SIPP median cc, unstand'
  npoor5='NAS pov except no geo, stand'
  npoor6='NAS pov except no geo, unstand'
  npoor7='pov using 3 param scale, afdc cc, stand'
  npoor8='pov with 3 param scale, afdc cc, unstand'
  npoor9='pov: 3 par scale, afdc cc, no geo, stand'
  npoor10='pov:3 par scale, afdc cc, no geo, unstd'
  npoor11='NAS pov except afdc median cc, stand'
  npoor12='NAS pov except afdc median cc, unstand'
  f_mv_fs='family food stamps income'
  f_mv_sl='school lunch income'
  housub='family housing subsidy income'
  fengval='family energy assistance subsidy amt'
  feitc='family EITC amt'
  ffica='family social security taxes amt'
  ffedtax='family federal taxes amt'
  fsttax='family state taxesamt'
  fcapgain='family capital gains amt'
  fcaploss='family capital losses amt'
  moop='fam med-out-of-pocket (moop) expenses'
  combexp='work-rel & cc costs, NAS imputation meth'
  combexpm='work-rel & cc costs, SIPP median meth'
  combadc='work-rel & cc costs, AFDC method'
  geo1='geographic adjustment to threshold'
  pova1a1='Fig 1 pov w/ high pt of threshold'
  pova1a2='Fig 1 pov w/ mid pt of threshold'
  pova1a3='Fig 1 pov w low pt of threshold'
  pova2a1='Fig 2 pov w low NAS equiv scale'
  pova2a2='Fig 2 pov w high NAS equiv scale'
  pova2a3='Fig 2 pov w mid NAS equiv scale'
  pova2a4='Fig 2 pov w sq root equiv scale'
  pova2a5='Fig 2 pov w 3 param equiv scale'
  pova2a6='Fig 2 pov w Canadian equiv scale'
  pova3a1='Fig 3 pov w geo adjustment'
  pova4a1='Fig 4 pov w food stamps'
  pova4a2='Fig 4 pov w school lunch'
  pova4a3='Fig 4 pov w food stmp & sch lunch'
  pova5a1='Fig 5 pov w housing subsidies'
  pova5a2='Fig 5 pov w heating subsidies'
  pova5a3='Fig 5 pov w housing & heating subs'
  pova6a1='Fig 6 pov w work exp, cc NAS model meth'
  pova6a2='Fig 6 pov w work exp, cc afdc meth'
  pova6a3='Fig 6 pov w work exp, median method'
  pova7a1='Fig 7 pov w fica tax'
  pova7a2='Fig 7 pov w fed tax'
  pova7a3='Fig 7 pov with state tax'
  pova7a4='Fig 7 pov w fed, state, eitc tax'
  pova7a5='Fig 7 pov w all taxes'
  pova8a1='Fig 8 pov w all transfers, no tax'
  pova8a2='Fig 8 pov w all transfers and taxes'
  pova9a1='Fig 9 pov w moop expenses'
  pova9a2='Fig 9 pov w moop & experimental thresh'
  pova10a1='Fig 10 pov w imputed rent in thresh'
  pova10a2='Fig 10 pov w net equity return in inc'
  pova10a3='Fig 10 pov with imp rent & net equity'
  nla2a1='Threshold used with pova2a1'
  nla2a2='Threshold used with pova2a2'
  nla2a3='Threshold used with pova2a3'
  nla2a4='Threshold used with pova2a4'
  nla2a5='Threshold used with pova2a5'
  nla2a6='Threshold used with pova2a6'
  nlgeo='Threshold w geo adjustment- pova3a1'
  defa4a1='Income def used w pova4a1'
  defa4a2='Income def used w pova4a2'
  defa4a3='Income def used w pova4a3'
  defa5a1='Income def used w pova5a1'
  defa5a2='Income def used w pova5a2'
  defa5a3='Income def used w pova5a3'
  defa6a1='Income def used w pova6a1'
  defa6a2='Income def used w pova6a2'
  defa6a3='Income def used w pova6a3'
  defa7a1='Income def used w pova7a1'
  defa7a2='Income def used w pova7a2'
  defa7a3='Income def used w pova7a3'
  defa7a4='Income def used w pova7a4'
  defa7a5='Income def used w pova7a5'
  defa8a1='Income def used w pova8a1'
  defa8a2='Income def used w pova8a2'
  defa9a1='Income def used w pova9a1'
  defa9a2='Income def used w pova9a2'
  defa10a2='Income def used w pova10a2'
  defa10a3='Income def used w pova10a3';
run;

proc format;

  value age
  1=  'lt 3'
  2=  '3 to 6'
  3=  '6 to 12'
  4=  '12 to 18'
  5=  '18 to 22'
  6=  '22 to 45'
  7=  '45 to 55'
  8=  '55 to 60'
  9=  '60 to 65'
  10=  '65 to 75'
  11=  '75+'      ;

value agecat
  1='lt 18'
  2='18-64'
  3='65+';

 value  a_sex
  1=  'male'
  2=  'female'  ;

value race
  1='white'
  2='black'
  3='other';

value hisp
  0='Non-Hispanic'
  1='Hispanic';

 value rac_hisp
  1=  'white not hisp'
  2=  'white hisp'
  3=  'black not hisp'
  4=  'black hisp'
  5=  'other not hisp'
  6=  'other hisp'     ;

 value fpersons
  1='1 person'
  2='2 persons'
  3='3 persons'
  4='4 persons'
  5='5 persons'
  6='6 persons'
  7='7 persons '
  8='8 persons'
  9='9 persons'
  10='10 or more persons';

 value fpersonr
  1='1 person'
  2='2 persons'
  3='3 persons'
  4='4 persons'
  5='5 persons'
  6='6 persons'
  7='7 or more persons ' ;

value adwk
  0='no workers in family'
  1='workers in family';

  value ms
  1=  'married sp present'
  3=  'married sp absent'
  4=  'widowed'
  5=  'divorced/separate '
  7=  'never married'  ;

 value educ
  9=  'Not in universe (under 25)'
  1=  'No high school'
  2=  'high school dip'
  3=  'some college'
  4=  'college degree'  ;

 value prcitshp
  1=  'native'
  4=  'naturalized citizen'
  5=  'not a citizen' ;

value dis
 1='disabled'
 2='not disabled'
 9='niu (under 16 or over 64 years of age)' ;

value severe
 0='not severely disabled'
 1='severely disabled';

value hea
1='excellent'
2='very good'
3='good'
4='fair'
5='poor'
9='niu' ;

value fkind
1='husband wife family'
2='other male reference person'
3='female reference person';

value region
1='Northeast'
2='Midwest'
3='South'
4='West';

value dv
1='unrelated individual'
2='Householder or spouse'
3='Other relative'
9='Not in universe (under 65)';

value famhead
0='not family head'
1='family head';

value ftype
1='primary family'
2='primary individual'
3='related subfamily'
4='unrelated subfamily'
5='secondary individual';

run;

proc contents data=pov2;
run;

proc freq data=pov2;
tables
     poor1 npoor1 npoor2 npoor3 npoor4 npoor5 npoor6 npoor7 npoor8
     npoor9 npoor10 npoor11 npoor12 pova1a1 pova1a2 pova1a3
     pova2a1 pova2a2 pova2a3 pova2a4 pova2a5 pova2a6 pova3a1
     pova4a1 pova4a2 pova4a3 pova5a1 pova5a2 pova5a3 pova6a1
     pova6a2 pova6a3 pova7a1 pova7a2 pova7a3 pova7a4 pova7a5
     pova8a1 pova8a2 pova9a1 pova9a2 pova10a1 pova10a2 pova10a3
     poor1*a_sex npoor1-npoor12*a_sex
     poor1*race npoor1-npoor12*race
     poor1*hisp npoor1-npoor12*hisp
     poor1*rac_hisp npoor1-npoor12*rac_hisp
     poor1*adwk npoor1-npoor12*adwk
     poor1*fkind npoor1-npoor12*fkind
     poor1*hg_reg npoor1-npoor12*hg_reg
     poor1*agecat npoor1-npoor12*agecat
     poor1*dv npoor1-npoor12*dv
     poor1*fpersonr npoor1-npoor12*fpersonr
     poor1*prcitshp npoor1-npoor12*prcitshp
     poor1*dis npoor1-npoor12*dis
     poor1*severe npoor1-npoor12*severe
     poor1*fpersons npoor1-npoor12*fpersons
     poor1*ms npoor1-npoor12*ms
     poor1*educ npoor1-npoor12*educ;
weight marsupwt;
run;

proc means data=pov2;
weight marsupwt;
run;