/********************************************************************************/
/**** This program reads in ASCII data and contains data steps to create     ****/
/**** marginal and experimental poverty measures for 1999 which are also     ****/
/**** contained in the public-use SAS datafile-- povpu99.ssd01.              ****/
/**** This will enable analysts to replicate the experimental poverty        ****/
/**** measures or appropriately recombine thresholds and income measures to  ****/
/**** examine new ones. Also included in this file are variable and value    ****/
/**** label statements.                                                      ****/
/**** For details on construction of various income and threshold measures,  ****/
/**** refer to the P60-205 report on Experimental Poverty Measures           ****/
/**** and its Appendix C.                                                    ****/
/********************************************************************************/

options ps=54 ls=80 fullstimer ;

libname datao '/folder/';
Filename povdat '/folder/povpu99.txt';

Data pov (compress=yes);

Infile povdat;
INPUT
     marsupwt adwk age agecat a_sex combadc combexp combexpm
     def017 def018 def019 defa10a2 defa10a3
     defa4a1 defa4a2 defa4a3 defa5a1 defa5a2
     defa5a3 defa6a1 defa6a2 defa6a3
     defa7a1 defa7a2
  /  defa7a3  defa7a4 defa7a5 defa8a1 defa8a2 defa9a1
     defa9a2 defmort dis dv educ famhead $ fcapgain
     fcaploss feitc fengval ffedtax ffica
     ffpos fh_seq fkind fpersonr fpersons
     fpovcut fsttax ftotval ftype f_mv_fs
     f_mv_sl geo1 hg_reg hisp housub
 /   h_seq moop ms nl1 nl2 nl3
     nl4 nl5 nl6 nl7 nl8 nl9 nl10
     nl11 nl12 nla2a1 nla2a2 nla2a3
     nla2a4 nla2a5 nla2a6 nlgeo npoor1
     npoor2 npoor3 npoor4 npoor5 npoor6 npoor7 npoor8
     npoor9 npoor10 npoor11 npoor12 pf_seq ph_seq
/    poor1 pova10a1 pova10a2 pova10a3 pova1a1 pova1a2 pova1a3
     pova2a1 pova2a2 pova2a3 pova2a4 pova2a5 pova2a6 pova3a1
     pova4a1 pova4a2 pova4a3 pova5a1 pova5a2 pova5a3 pova6a1
     pova6a2 pova6a3 pova7a1 pova7a2 pova7a3 pova7a4
     pova7a5 pova8a1 pova8a2 pova9a1 pova9a2 pov_univ
     ppposold prcitshp race racer scaleb scalec
     scaleph scalepl scalepm scalesq severe
     hea thrhigh thrir thrlow thrmed
/    nl13-nl24 npoor13-npoor24;

run;

Data pov2;
set pov;

/* If using the ASCII data set, use following statement to get
   frequency tallies in 1000s. Note: do not use the following
   statement if reading data from the SAS data sets, where the
   figures are already in 1000s */
marsupwt=marsupwt/100000;

/** Calculate poverty measures **/
if pov_univ=1 then DO;   /* Do loop for those in the poverty universe */

/* official poverty measure */
poor1=0;
if ftotval lt fpovcut then poor1=1;

/**** resource definintions used in various experimental poverty measures ****/
def001= ftotval;               /* official income definition */
def013= def001 - ffica + fcapgain - fcaploss - ffedtax - fsttax + feitc
        + f_mv_fs + housub + f_mv_sl + fengval -  moop;
def017= def013 - combexp;      /* NAS Panel definition */
def018= def013 - combexpm;     /* NAS but with SIPP median child care method */
def019= def013 - combadc;      /* NAS but with AFDC cc method */

/****  Below are thresholds used in experimental poverty measures  ****/
/** Standardization factors at the end of the odd-numbered tresholds           **/
/** represent the factors used in 1997 to make the                             **/
/** experimental rates equal the official rate in that year.                   **/
/** See the 1999 poverty report, P60-210 (p. xvii), downloadable               **/
/** from the Census poverty web page, for more explanation of standardization  **/

/* nl1-nl12, which are the Consumer Expediture Survey Thresholds, are missing in 1999.
   Only the available this year are nl13-nl24, which use 1997 Consumer Expediture Survey
   Thresholds updated to 1999 using the consumer price index (CPI) */

nl1=.;
nl2=.;
nl3=.;
nl4=.;
nl5=.;
nl6=.;
nl7=.;
nl7=.;
nl8=.;
nl9=.;
nl10=.;
nl11=.;
nl12=.;

nl13=16606*scalepm*geo1*.9119;  /* nl1 cpi back-dated */
nl14=16606*scalepm*geo1;        /* nl2 cpi back-dated */

nl15=16606*scalepm*geo1*.8962;   /* nl3 cpi back-dated */
nl16=16606*scalepm*geo1;        /* nl4 cpi back-dated */

nl17=16606*scalepm*.9031;       /* nl5 cpi back-dated */
nl18=16606*scalepm;             /* nl6 cpi back-dated */

nl19=16606*scaleb*geo1*.8877;    /* nl7 cpi back-dated */
nl20=16606*scaleb*geo1;          /* nl8 cpi back-dated */

nl21=16606*scaleb*.8791;         /* nl9 cpi back-dated */
nl22=16606*scaleb;               /* nl10 cpi back-dated */

nl23=16606*scalepm*geo1*.9087;   /* nl11 cpi back-dated */
nl24=16606*scalepm*geo1;         /* nl12 cpi back-dated */


/* 24 experimental poverty measures */

/* npoor1-npoor12 missing in 1999 */
npoor1=.;
npoor2=.;
npoor3=.;
npoor4=.;
npoor5=.;
npoor6=.;
npoor7=.;
npoor8=.;
npoor9=.;
npoor10=.;
npoor11=.;
npoor12=.;

/* 12 experimental methods, cpi back-dated. Same as npoor13-npoor24 are
   equal npoor1-npoor12 in 1997 */
npoor13=0;
if def017 lt nl13 then npoor13=1;    /* panel method 1 cpi back-dated */
npoor14=0;
if def017 lt nl14 then npoor14=1;    /* panel method 2 cpi back-dated */
npoor15=0;
if def018 lt nl15 then npoor15=1;     /* panel method 3 cpi back-dated */
npoor16=0;
if def018 lt nl16 then npoor16=1;    /* panel method 4 cpi back-dated */
npoor17=0;
if def017 lt nl17 then npoor17=1;    /* panel method 5 cpi back-dated */
npoor18=0;
if def017 lt nl18 then npoor18=1;    /* panel method 6 cpi back-dated */
npoor19=0;
if def019 lt nl19 then npoor19=1;    /* panel method 7 cpi back-dated */
npoor20=0;
if def019 lt nl20 then npoor20=1;    /* panel method 8 cpi back-dated */
npoor21=0;
if def019 lt nl21 then npoor21=1;    /* panel method 9 cpi back-dated */
npoor22=0;
if def019 lt nl22 then npoor22=1;    /* panel method 10 cpi back-dated */
npoor23=0;
if def019 lt nl23 then npoor23=1;    /* panel method 11 cpi back-dated */
npoor24=0;
if def019 lt nl24 then npoor24=1;    /* panel method 12 cpi back-dated */



/*****************************************************************************************/
/** Below are various marginal poverty measures contained in the Experimental Poverty   **/
/**  Report, P60-205. Each poverty measure has four suffix numbers and letters. The     **/
/**  first three refer to the P-60 report table in which the poverty rates              **/
/**  are listed, and the last differentiates the poverty measures within the            **/
/**  table. For example, variable pova1a1 suffix refer to the first of three            **/
/**  marginal poverty measures listed in Appendix table a1a                             **/
/*****************************************************************************************/

pova1a1=.; /* missing in 1999 */

pova1a2=.; /* missing in 1999 */

pova1a3=.; /* missing in 1999 */

pova2a1=0;
nla2a1=16895*scalepl;
if ftotval lt nla2a1 then pova2a1=1;

pova2a2=0;
nla2a2=16895*scaleph;
if ftotval lt nla2a2 then pova2a2=1;

pova2a3=0;
nla2a3=16895*scalepm;
if ftotval lt nla2a3 then pova2a3=1;

pova2a4=0;
nla2a4=16895*scalesq;
if ftotval lt nla2a4 then pova2a4=1;

pova2a5=0;
nla2a5=16895*scaleb;
if ftotval lt nla2a5 then pova2a5=1;

pova2a6=0;
nla2a6=16895*scalec;
if ftotval lt nla2a6 then pova2a6=1;

pova3a1=0;
nlgeo=fpovcut*geo1;
if ftotval lt nlgeo then pova3a1=1;

pova4a1=0;
defa4a1=ftotval+f_mv_fs;
if defa4a1 lt fpovcut then pova4a1=1;

pova4a2=0;
defa4a2=ftotval+f_mv_sl;
if defa4a2 lt fpovcut then pova4a2=1;

pova4a3=0;
defa4a3=ftotval+f_mv_fs+f_mv_sl;
if defa4a3 lt fpovcut then pova4a3=1;

pova5a1=0;
defa5a1=ftotval+housub;
if defa5a1 lt fpovcut then pova5a1=1;

pova5a2=0;
defa5a2=ftotval+fengval;
if defa5a2 lt fpovcut then pova5a2=1;

pova5a3=0;
defa5a3=ftotval+housub+fengval;
if defa5a3 lt fpovcut then pova5a3=1;

pova6a1=0;
defa6a1=ftotval-combexp;
if defa6a1 lt fpovcut then pova6a1=1;

pova6a2=0;
defa6a2=ftotval-combadc;
if defa6a2 lt fpovcut then pova6a2=1;

pova6a3=0;
defa6a3=ftotval-combexpm;
if defa6a3 lt fpovcut then pova6a3=1;

pova7a1=0;
defa7a1=ftotval-ffica;
if defa7a1 lt fpovcut then pova7a1=1;

pova7a2=0;
defa7a2=ftotval-ffedtax;
if defa7a2 lt fpovcut then pova7a2=1;

pova7a3=0;
defa7a3=ftotval-fsttax;
if defa7a3 lt fpovcut then pova7a3=1;

pova7a4=0;
defa7a4=ftotval-ffedtax-fsttax+feitc;
if defa7a4 lt fpovcut then pova7a4=1;

pova7a5=0;
defa7a5=ftotval-ffedtax-fsttax-ffica+feitc+fcapgain-fcaploss;
if defa7a5 lt fpovcut then pova7a5=1;

pova8a1=0;
defa8a1=ftotval+ f_mv_fs + housub + f_mv_sl + fengval;
if defa8a1 lt fpovcut then pova8a1=1;

pova8a2=0;
defa8a2=ftotval+f_mv_fs+housub+f_mv_sl+fengval+feitc-ffica-ffedtax-fsttax+fcapgain
        - fcaploss;
if defa8a2 lt fpovcut then pova8a2=1;

pova9a1=0;
defa9a1=ftotval-moop;
if defa9a1 lt fpovcut then pova9a1=1;

pova9a2=.; /* missing in 1999 */

pova10a1=.; /* missing in 1999 */

pova10a2=.; /* missing in 1999 */

pova10a3=.; /* missing in 1999 */

End; /* end pov_univ */

Label
  h_seq='household id in cps household file'
  fh_seq='houshold id in cps family file'
  ph_seq='household id in cps person file'
  ffpos='family record number'
  pf_seq='family record # in cps person file'
  ppposold='person record number'
  age='11 category age recode'
  agecat='3 category age recode'
  a_sex='sex'
  educ='educational attainment'
  race='3 category race recode'
  hisp='Hispanic indicator'
  racer='race/hispanic recode'
  fpersons='# persons in family recode'
  fpersonr='# persons in family recode #2'
  adwk='presence of working adult in family'
  prcitshp='citizenship recode'
  dis='disability indicator'
  severe='severe disability indicator'
  hea='health indicator'
  fkind='kind of family'
  ms='marital status indicator'
  hg_reg='region of residence'
  dv='elderly person fam relationship status'
  famhead='family head indicator'
  ftype='family type'
  marsupwt='March supplement final weight'
  pov_univ='whether in poverty universe'
  ftotval='total family income'
  def001='family income- official resource defn'
  def017='NAS Panel definition of resources'
  def018='NAS defn except w/ SIPP median cc est'
  def019='NAS defn except w/ AFDC cc valuation'
  defmort='offic inc defn+net return home equity'
  fpovcut='official pov threshold for family'
  thrlow='low $ of NAS threshold range'
  thrmed='midpoint $ of NAS threshold range'
  thrhigh='highpoint of NAS threshold range'
  thrir='threshold with imputed rent'
  scalepl='low NAS equivalence scale-- (A+.7K).65'
  scaleph='high NAS equiv scale-- (A+.7k).75'
  scalepm='mid NAS equiv scale (A+.7k).70'
  scalesq='square root eqiv scale (A+K).50'
  scaleb='three parameter scale'
  scalec='Canadian equivalence scale'
  nl1='threshold used to estimate npoor1 status'
  nl2='threshold used to estimate npoor2 status'
  nl3='threshold used to estimate npoor3 status'
  nl4='threshold used to estimate npoor4 status'
  nl5='threshold used to estimate npoor5 status'
  nl6='threshold used to estimate npoor6 status'
  nl7='threshold used to estimate npoor7 status'
  nl8='threshold used to estimate npoor8 status'
  nl9='threshold used to estimate npoor9 status'
  nl10='threshold used for npoor10 status'
  nl11='threshold used for npoor11 status'
  nl12='threshold used for npoor12 status'
  nl13='threshold used to estimate npoor13 status'
  nl14='threshold used to estimate npoor14 status'
  nl15='threshold used to estimate npoor15 status'
  nl16='threshold used to estimate npoor16 status'
  nl17='threshold used to estimate npoor17 status'
  nl18='threshold used to estimate npoor18 status'
  nl19='threshold used to estimate npoor19 status'
  nl20='threshold used to estimate npoor20 status'
  nl21='threshold used to estimate npoor21 status'
  nl22='threshold used for npoor22 status'
  nl23='threshold used for npoor23 status'
  nl24='threshold used for npoor24 status'
  poor1='official poverty indicator'
  npoor1='pov indicator, NAS standardized method'
  npoor2='pov indicator, NAS unstandardized method'
  npoor3='NAS pov except SIPP median cc, stand'
  npoor4='NAS pov except SIPP median cc, unstand'
  npoor5='NAS pov except no geo, stand'
  npoor6='NAS pov except no geo, unstand'
  npoor7='pov using 3 param scale, afdc cc, stand'
  npoor8='pov with 3 param scale, afdc cc, unstand'
  npoor9='pov: 3 par scale, afdc cc, no geo, stand'
  npoor10='pov:3 par scale, afdc cc, no geo, unstd'
  npoor11='NAS pov except afdc median cc, stand'
  npoor12='NAS pov except afdc median cc, unstand'
  npoor13='NAS standardized pov, cpi-updated thresh'
  npoor14='NAS unstand pov, cpi-updated threshold'
  npoor15='NAS excep SIPP median cc, stand, cpi thr'
  npoor16='NAS excep SIPP median cc, unstd, cpi thr'
  npoor17='NAS pov except no geo, stand, cpi thresh'
  npoor18='NAS pov except no geo, unstand, cpi thr'
  npoor19='pov w 3 par scale, afdc cc, std, cpi thr'
  npoor20='pov w 3 par scale, afdc cc, unstd, cpi t'
  npoor21='pov 3 p scale, afdc cc, no geo, std, cpi'
  npoor22='pov3 p scle, afdc cc, no geo, unstd, cpi'
  npoor23='NAS pov excep afdc median cc, stand, cpi'
  npoor24='NAS pov excep afdc median cc, unstd, cpi'
  f_mv_fs='family food stamps income'
  f_mv_sl='school lunch income'
  housub='family housing subsidy income'
  fengval='family energy assistance subsidy amt'
  feitc='family EITC amt'
  ffica='family social security taxes amt'
  ffedtax='family federal taxes amt'
  fsttax='family state taxesamt'
  fcapgain='family capital gains amt'
  fcaploss='family capital losses amt'
  moop='fam med-out-of-pocket (moop) expenses'
  combexp='work-rel & cc costs, NAS imputation meth'
  combexpm='work-rel & cc costs, SIPP median meth'
  combadc='work-rel & cc costs, AFDC method'
  geo1='geographic adjustment to threshold'
  pova1a1='Fig 1 pov w/ high pt of threshold'
  pova1a2='Fig 1 pov w/ mid pt of threshold'
  pova1a3='Fig 1 pov w low pt of threshold'
  pova2a1='Fig 2 pov w low NAS equiv scale'
  pova2a2='Fig 2 pov w high NAS equiv scale'
  pova2a3='Fig 2 pov w mid NAS equiv scale'
  pova2a4='Fig 2 pov w sq root equiv scale'
  pova2a5='Fig 2 pov w 3 param equiv scale'
  pova2a6='Fig 2 pov w Canadian equiv scale'
  pova3a1='Fig 3 pov w geo adjustment'
  pova4a1='Fig 4 pov w food stamps'
  pova4a2='Fig 4 pov w school lunch'
  pova4a3='Fig 4 pov w food stmp & sch lunch'
  pova5a1='Fig 5 pov w housing subsidies'
  pova5a2='Fig 5 pov w heating subsidies'
  pova5a3='Fig 5 pov w housing & heating subs'
  pova6a1='Fig 6 pov w work exp, cc NAS model meth'
  pova6a2='Fig 6 pov w work exp, cc afdc meth'
  pova6a3='Fig 6 pov w work exp, median method'
  pova7a1='Fig 7 pov w fica tax'
  pova7a2='Fig 7 pov w fed tax'
  pova7a3='Fig 7 pov with state tax'
  pova7a4='Fig 7 pov w fed, state, eitc tax'
  pova7a5='Fig 7 pov w all taxes'
  pova8a1='Fig 8 pov w all transfers, no tax'
  pova8a2='Fig 8 pov w all transfers and taxes'
  pova9a1='Fig 9 pov w moop expenses'
  pova9a2='Fig 9 pov w moop & experimental thresh'
  pova10a1='Fig 10 pov w imputed rent in thresh'
  pova10a2='Fig 10 pov w net equity return in inc'
  pova10a3='Fig 10 pov with imp rent & net equity'
  nla2a1='Threshold used with pova2a1'
  nla2a2='Threshold used with pova2a2'
  nla2a3='Threshold used with pova2a3'
  nla2a4='Threshold used with pova2a4'
  nla2a5='Threshold used with pova2a5'
  nla2a6='Threshold used with pova2a6'
  nlgeo='Threshold w geo adjustment- pova3a1'
  defa4a1='Income def used w pova4a1'
  defa4a2='Income def used w pova4a2'
  defa4a3='Income def used w pova4a3'
  defa5a1='Income def used w pova5a1'
  defa5a2='Income def used w pova5a2'
  defa5a3='Income def used w pova5a3'
  defa6a1='Income def used w pova6a1'
  defa6a2='Income def used w pova6a2'
  defa6a3='Income def used w pova6a3'
  defa7a1='Income def used w pova7a1'
  defa7a2='Income def used w pova7a2'
  defa7a3='Income def used w pova7a3'
  defa7a4='Income def used w pova7a4'
  defa7a5='Income def used w pova7a5'
  defa8a1='Income def used w pova8a1'
  defa8a2='Income def used w pova8a2'
  defa9a1='Income def used w pova9a1'
  defa9a2='Income def used w pova9a2'
  defa10a2='Income def used w pova10a2'
  defa10a3='Income def used w pova10a3';

run;

proc format;

  value age
  1=  'lt 3'
  2=  '3 to 6'
  3=  '6 to 12'
  4=  '12 to 18'
  5=  '18 to 22'
  6=  '22 to 45'
  7=  '45 to 55'
  8=  '55 to 60'
  9=  '60 to 65'
  10=  '65 to 75'
  11=  '75+'      ;

value agecat
  1='lt 18'
  2='18-64'
  3='65+';

 value  a_sex
  1=  'male'
  2=  'female'  ;

value race
  1='white'
  2='black'
  3='other';

value hisp
  0='Non-Hispanic'
  1='Hispanic';

 value racer
  1=  'white not hisp'
  2=  'black not hisp'
  3=  'hispanic'
  4=  'other' ;

 value fpersons
  1='1 person'
  2='2 persons'
  3='3 persons'
  4='4 persons'
  5='5 persons'
  6='6 persons'
  7='7 persons '
  8='8 persons'
  9='9 persons'
  10='10 or more persons';

 value fpersonr
  1='1 person'
  2='2 persons'
  3='3 persons'
  4='4 persons'
  5='5 persons'
  6='6 persons'
  7='7 or more persons ' ;

value adwk
  0='no workers in family'
  1='workers in family';

  value ms
  1=  'married sp present'
  3=  'married sp absent'
  4=  'widowed'
  5=  'divorced/separate '
  7=  'never married'  ;

 value educ
  9=  'Not in universe (under 25)'
  1=  'No high school'
  2=  'high school dip'
  3=  'some college'
  4=  'college degree'  ;

 value prcitshp
  1=  'native'
  4=  'naturalized citizen'
  5=  'not a citizen' ;

value dis
 1='disabled'
 2='not disabled'
 9='niu (under 16 or over 64 years of age)' ;

value severe
 0='not severely disabled'
 1='severely disabled';

value hea
1='excellent'
2='very good'
3='good'
4='fair'
5='poor'
9='niu' ;

value fkind
1='husband wife family'
2='other male reference person'
3='female reference person';

value hg_reg
1='Northeast'
2='Midwest'
3='South'
4='West';

value dv
1='unrelated individual'
2='Householder or spouse'
3='Other relative'
9='Not in universe (under 65)';

value famhead
0='not family head'
1='family head';

value ftype
1='primary family'
2='primary individual'
3='related subfamily'
4='unrelated subfamily'
5='secondary individual';

value pov_univ
0='not in the poverty universe'
1='in the poverty universe';

run;

proc contents data=pov2;
run;

proc freq data=pov2;
tables
     poor1 npoor1-npoor24 pova1a1 pova1a2 pova1a3
     pova2a1 pova2a2 pova2a3 pova2a4 pova2a5 pova2a6 pova3a1
     pova4a1 pova4a2 pova4a3 pova5a1 pova5a2 pova5a3 pova6a1
     pova6a2 pova6a3 pova7a1 pova7a2 pova7a3 pova7a4 pova7a5
     pova8a1 pova8a2 pova9a1 pova9a2 pova10a1 pova10a2 pova10a3
     poor1*a_sex npoor1-npoor24*a_sex
     poor1*race npoor1-npoor24*race
     poor1*hisp npoor1-npoor24*hisp
     poor1*racer npoor1-npoor24*racer
     poor1*adwk npoor1-npoor24*adwk
     poor1*fkind npoor1-npoor24*fkind
     poor1*hg_reg npoor1-npoor24*hg_reg
     poor1*agecat npoor1-npoor24*agecat
     poor1*fpersonr npoor1-npoor24*fpersonr
     poor1*prcitshp npoor1-npoor24*prcitshp
     poor1*dis npoor1-npoor24*dis
     poor1*severe npoor1-npoor24*severe
     poor1*fpersons npoor1-npoor24*fpersons
     poor1*ms npoor1-npoor24*ms
     poor1*educ npoor1-npoor24*educ;
weight marsupwt;
run;

proc means data=pov2;
weight marsupwt;
run;